Stanzwerkzeug

Erweiterte Module > Creo Elements/Direct Sheet Metal > Creo Elements/Direct Sheet Metal Anpassung > Stanzwerkzeug

Stanzwerkzeug

In diesem Kapitel werden die folgenden Themen behandelt:

• Parametrische Stanzwerkzeuge

◦ Parametrisches Stanzwerkzeug einer vorhandenen Art hinzufügen

• Parametrische Stanzwerkzeugarten

◦ Struktur der Definition einer parametrischen Stanzwerkzeugart

◦ Parametrisches Stanzwerkzeug - Beispiel

◦ Parametrische Stanzwerkzeugart hinzufügen

• Nicht parametrische Stanzwerkzeugarten

◦ Eintrag für nicht parametrische Stanzwerkzeugart hinzufügen

Für den Stanzprozess umfasst die Definitionsdatei einer Creo Elements/Direct Sheet Metal Fertigungsstätte Folgendes:

• Tabelle "Stanzwerkzeugarten", in der die Stanzwerkzeugarten angegeben sind (z. B. "Sicherung, Nase innen").

• Satz von Werkzeugtabellen. Jede dieser Tabellen gibt die Bemaßungen und andere Prozessparameter der einzelnen Werkzeuge einer bestimmten Stanzwerkzeugart an. Die Tabelle "Sicherung, Nase innen" enthält z. B. eine separate Zeile für jede Nut im Werkzeug. Wenn eine bestimmte Stanzwerkzeugart durch ein einzelnes Stanzwerkzeug dargestellt wird, enthält die zugehörige Werkzeugtabelle nur einen einzelnen Parameterdatensatz (eine einzelne Zeile mit Tabellenwerten).

Creo Elements/Direct Sheet Metal Stanzwerkzeuge führen den Vorgang Fräsen in Creo Elements/Direct Modeling für die Teile durch, auf die sie angewendet werden.

Parametrische Stanzwerkzeuge

Ab CoCreate Sheet Metal Version 4.5 sind alle in der Definitionsdatei der Beispielfertigungsstätte sha_demoshop.lsp angegebenen Stanzwerkzeugarten "parametrische Werkzeuge". Das bedeutet, dass der Benutzer während der Ausführung eine geeignete Werkzeugbemaßung aus einer Liste auswählt. Sie (oder der TDB-Administrator) können in der TDB zusätzliche Werkzeuggrößen angeben, indem Sie eine Zeile (einen weiteren Parameterdatensatz) in der zugehörigen Werkzeugtabelle hinzufügen.

Parametrisches Stanzwerkzeug einer vorhandenen Art hinzufügen

Um ein parametrisches Stanzwerkzeug einer vorhandenen Art hinzuzufügen, müssen Sie die neue Stanzwerkzeug-Spezifikation (eine zusätzliche Zeile) in der zugehörigen Stanzwerkzeugtabelle hinzufügen. Verwenden Sie die Technologiedatenbank-Liste (siehe Die Technologiedatenbank-Liste), oder ändern Sie die zugrunde liegende TDB-Tabelle manuell.

Wenn Sie z. B. ein Stanzwerkzeug der Art "rnd" hinzufügen möchten, gehen Sie folgendermaßen vor:

1. Öffnen Sie die Definitionsdatei für die Fertigungsstätte (z. B. Ihre Arbeitskopie der Datei sha_demoshop.lsp).

2. Zeigen Sie die Tabelle "Rundloch" in der Fertigungsstätten-Definitionsdatei an. Diese Tabelle wird unten angezeigt.

(sha-define-shop-table "rnd"
:TABLE-TITLE "Round"
:COLUMNS
(:DIA :TOOL_ID :DESCR :MIN_THICK :MAX_THICK :PREFERENCE :ADVICE )
:COLUMN-NAMES
( "Dia" "Tool Id" "Descr" "Min Thick" "Max Thick" "Pref" "Advice")
:UNITS
( :mm nil nil :mm :mm nil nil)
:CONTENTS
(
(1.10 "01004" "RW" 0 100 :PREF "-")
(2.00 "01012" "CN" 0 100 :NONPREF "-")
(3.00 "01024" "NE" 0 100 :PREF "-")
(4.00 "01042" "EM" 0 100 :PREF "-")
(8.00 "01116" "TAQ" 0 100 :NONPREF "-")
(10.00 "01136" "TAU" 0 100 :PREF "-")
(12.70 "01158" "TAV" 0 100 :PREF "-")
(20.00 "01190" "TBQ" 0 100 :NONPREF "-")
)
:KEY (:DIA )
:DISPLAY (:DIA :PREFERENCE :ADVICE)
:FLAT-TEXT (:TOOL_ID)
:HELP "sha_rnd"
; unique, not displayable column entries
:PROF_FNC sha-rnd-profile
)

3. Fügen Sie unter :CONTENTS die Zeile hinzu, die das zusätzliche Stanzwerkzeug festlegt. Für "demoshop" umfasst jede "Rundloch"-Werkzeugangabe Einträge für die folgenden Spalten:

:DIA	Werkzeugdurchmesser.
:TOOL_ID	Identifikationsnummer des Werkzeugs.
:DESCR	Aussagekräftiger Werkzeugname.
:MIN_THICK	Minimale Materialdicke, für die das Werkzeug konstruiert wurde.
:MAX_THICK	Maximale Materialdicke, für die das Werkzeug konstruiert wurde.
:PREFERENCE	Vorgabestatus: ":VORZUG" für bevorzugte Werkzeuge oder ":NICHTVORZUG" für nicht bevorzugte Werkzeuge.
:ADVICE	Creo Elements/Direct Sheet Metal füllt diese Spalte gemäß den Überprüfungen im Hinblick auf :MAX_THICK und/oder :MIN_THICK (wenn diese Einträge vorhanden sind).
:FLAT-TEXT	Wie in "Allgemeine Struktur von Fertigungsstätten-Tabellen".

Der folgende Parameterdatensatz (Zeile in Werkzeugtabelle) ist ein Beispiel für eine zusätzliche "Rundloch"-Werkzeugangabe.

(6.00 "01042" "EM" 0 1.5 ":NONPREF" "-")

Der Durchmesser der mit diesem neuen Stanzwerkzeug erzeugten Bohrung beträgt 6,00 mm. Die ID-Nummer lautet 01042. Der Name ist EM. Dabei handelt es sich um ein nicht bevorzugtes Werkzeug, das für eine Dicke bis zu 1,5 mm konstruiert wurde. Der Eintrag "-" ist der Standardeintrag für die Spalte :ADVICE. Während der Ausführung wird der Eintrag "-" für die Spalte :ADVICE dynamisch durch das Ergebnis der Werkzeugprüfung ersetzt, wenn das Werkzeug in der Werkzeugauswahltabelle enthalten ist.

Parametrische Stanzwerkzeugarten

Jede parametrische Stanzwerkzeugart wird durch eine spezielle C++- oder LISP-basierte Funktion definiert. Diese Funktion definiert eine Folge von Creo Elements/Direct Modeling 2D-Befehlen, die das erforderliche Stanzprofil in einer speziellen Arbeitsebene erstellen. Zum Positionieren des Stanzwerkzeugs am Werkstück werden Ausrichtungspunkte bereitgestellt.

Für Englisch sind die LISP-basierten Funktionen, die diese parametrischen Stanzwerkzeugobjekte definieren, in der folgenden Datei enthalten:

$INSTALLDIR/personality/sd_customize/SheetAdvisor/punch_fncs/sha_punch_functions.lsp

Für andere Sprachen sind die Funktionen in der folgenden Datei enthalten:

$INSTALLDIR/personality/<Sprache>/sd_customize/SheetAdvisor/punch_fncs/sha_punch_functions.lsp

Wenn Sie die Funktionen für Ihre eigenen parametrischen Stanzwerkzeuge anpassen möchten, erstellen Sie zunächst eine Arbeitskopie dieser Datei. Verwenden Sie für die Datei einen Namen wie z. B. my_punch_func.lsp.

Die entsprechende Funktion muss in der Spalte :PROF_FNC des Werkzeugs referenziert werden, das von ihr definiert wird. Creo Elements/Direct Sheet Metal füllt diese Funktion mit den gesamten Werkzeugtabelleneinträgen für die ausgewählte Werkzeugart sowie mit Angaben zur Blechdicke und der aktuellen Creo Elements/Direct Modeling Auflösung. Die Ausgabe der Funktion umfasst das resultierende Profil, das in der Arbeitsebene des Stanzwerkzeugs erstellt wird.

Creo Elements/Direct Sheet Metal erstellt mit diesen Daten Abstandsprüfungszonen, die um das Stanzwerkzeug angezeigt werden, bevor es auf dem Blechteil platziert wird. Nachdem der Benutzer das Werkzeug positioniert hat, verwendet Creo Elements/Direct Sheet Metal das Profil zum Fräsen des ausgewählten Blechteils. Die Frästiefe entspricht in der Regel der Blechdicke. Creo Elements/Direct Sheet Metal erstellt die Angaben zum Stanzformelement aus dem resultierenden Ausschnitt.

Für die LISP-Funktionsdateien wird die Groß-/Kleinschreibung nicht beachtet.

Struktur der Definition einer parametrischen Stanzwerkzeugart

Die Struktur des Stanzwerkzeugs in Creo Elements/Direct Sheet Metal basiert auf LISP-Paketdefinitionen und Stanzwerkzeugfunktionen.

LISP-Paketdefinitionen

Die im Lieferumfang von Creo Elements/Direct Sheet Metal enthaltene Beispieldatei sha_punch_functions.lsp stellt Funktionen für das Sheet-Advisor-Paket bereit. Es werden andere Funktionen verwendet, die über das oli-Paket (offene LISP-Schnittstelle) von Creo Elements/Direct Modeling bereitgestellt werden.

• (in-package :sheet-advisor)

• (use-package :oli)

Funktionen

• Die für jedes Stanzwerkzeug in der Beispieldatei sha_punch_functions.lsp definierte Funktion muss in der Spalte :PROF_FNC der Werkzeugtabelle angegeben sein, der sie zugeordnet ist. Konventionsgemäß beginnt der Funktionsname mit sha- und endet mit -profile. Er identifiziert eine Funktion im Creo Elements/Direct Sheet Metal (sha) Paket, das das Werkzeugprofil erstellt.

defun sha-<function_name>-profile

• Der Deklaration des Funktionsnamens folgen die Werkzeugparameter, die von dieser Funktion verwendet werden. Die Parameternamen müssen mit den in der Werkzeugtabelle angegebenen Spaltennamen oder den Standardparametern :THICKNESS (Blechdicke) und/oder :RESOLUTION (aktuelle Systemgenauigkeit). übereinstimmen. Die Daten für diese Parameter stammen aus den Spalten der zugehörigen TDB-Tabelle. Wenn z. B. parameter_1 als slot_length definiert ist, stammen die entsprechenden Bemaßungen aus der Spalte slot_length der zugehörigen Werkzeugtabelle. Die Anweisung &allow-other-keys gilt für alle anderen Parameter, die nicht von dieser Funktion verwendet werden.

(
parameter_1
parameter_2
...
parameter_n
thickness
resolution

• Der nächste Block (beginnend mit let) definiert die standardmäßigen lokalen Variablen:

◦ result

Als Rückgabewert verwendet.

◦ tool-wp

Name der Arbeitsebene, in der das Stanzprofil erstellt wird. Der tatsächliche Name wird durch die Funktion sha-tool-wp angegeben. Die Anweisung tool-wp gibt den Namen der Arbeitsebene an, in der das Profil des Stanzwerkzeugs positioniert wird.

(let ((result nil)
(tool-wp (sha-tool-wp)
(local-variable1 local-value1)
(... ...)
)

• Der nächste Block erzeugt die Arbeitsebene, in der das Stanzprofil erstellt wird.

(create_workplane :new
:name tool-wp
)

• Der nächste Block erstellt das Werkzeugprofil mithilfe von regulären Befehlen in Creo Elements/Direct Modeling. Beispiel:

(POLYGON
(gpnt2d ...)
(gpnt2d ...)
...
(gpnt2d ...))
(ARC :CEN_RAD_ANG
(gpnt2d ...)
radius
angle
)

• Der nächste Block erstellt Ausrichtungspunkte. Der zentrale Ausrichtungspunkt muss am Ursprung positioniert sein (0,0). Die anderen Ausrichtungspunkte werden um den zentralen Ausrichtungspunkt positioniert.

(C_POINT
0,0
(gpnt2d x1 y1)
(gpnt2d x2 y2)
(gpnt2d x3 y3)
(gpnt2d .. ..)
(gpnt2d xn yn)
)

• Das resultierende Profil wird aus der Arbeitsebene mithilfe einer speziellen Creo Elements/Direct Sheet Metal Funktion extrahiert.

(setq result (sha-profile-of-wp tool-wp_(PPP

• Die Arbeitsebene des Werkzeugs wird gelöscht.

(delete_3d (sha-absolute-name tool-wp))

• Das Ergebnis wird auf den letzten LISP-Wert (der als Rückgabewert dient) gesetzt.

result
)
)

Parametrisches Stanzwerkzeug - Beispiel

Der folgende Abschnitt ist ein Auszug aus der Beispieldatei sha_punch_functions.lsp, die im Lieferumfang von Creo Elements/Direct Sheet Metal enthalten ist. Darin wird die Verwendung der Funktionssyntax veranschaulicht, die in den vorherigen Abschnitten beschrieben wurde. In diesem Abschnitt des Beispiels wird die Funktion des Stanzwerkzeugs "Rasthalterung" definiert.

;=================================================
;
; CONNECTOR
;
;=================================================
(defun sha-con
(
out_length
out_width
in_length
in_width
radius
n_rad
(resolution 0.000001)
)
(let ((result nil)
(tool-wp (sha-tool-wp))
)
(create_workplane :new
:name tool-wp
)
;********* create Profile *******
(POLYGON
(gpnt2d 0 (/ out_width 2))
(gpnt2d (/ in_length 2) (/ out_width 2))
(gpnt2d (/ in_length 2) (/ in_width 2))
(gpnt2d (/ out_length 2) (/ in_width 2))
(gpnt2d (/ out_length 2) 0)
)
(when (> n_rad resolution)
(FILLET :CREATE
:FILLET_RADIUS n_rad
(gpnt2d (/ in_length 2) (/ out_width 2))
)
)
(when (> radius resolution)
(FILLET :CREATE
:FILLET_RADIUS radius
(gpnt2d (/ out_length 2) (/ in_width 2))
)
)
(MIRROR_2D
:SELECT :all_2d
:HORIZONTAL
0,0
)
(MIRROR_2D
:SELECT :all_2d
:VERTICAL
0,0
)
;******** create Adjustpoints ******
(C_POINT
0,0
; (gpnt2d dist 0)
; (gpnt2d (- dist) 0)
; (gpnt2d 0 (* (cos (deg-to-rad 30)) (- dist)))
; (gpnt2d dist (* (cos (deg-to-rad 30)) (- dist)))
; (gpnt2d (- dist) (* (cos (deg-to-rad 30)) (- dist)))
; (gpnt2d 0 (* (cos (deg-to-rad 30)) dist))
; (gpnt2d dist (* (cos (deg-to-rad 30)) dist))
; (gpnt2d (- dist) (* (cos (deg-to-rad 30)) dist))
)
(setq result (sha-profile-of-wp tool-wp))
(delete_3d (sha-absolute-name tool-wp))
result
)
)

Parametrische Stanzwerkzeugart hinzufügen

Sie können das im vorherigen Abschnitt gezeigte Beispiel als Vorlage verwenden, um schnell eine benutzerdefinierte Stanzwerkzeugart zu erstellen. Die folgende Übung veranschaulicht die Erstellung und Implementierung einer dreieckigen Stanzwerkzeugart.

Diese Übung umfasst die folgenden Phasen:

1. Phase 1: Arbeitsebene und Profil sowie Ausrichtungspunkte erstellen

2. Phase 2: Neue Stanzwerkzeugart in der Tabelle "Stanzwerkzeugarten" deklarieren

3. Phase 3: Werkzeugtabelle für die neue Stanzwerkzeugart hinzufügen

4. Phase 4: Neue Werkzeugfunktion in der Datei "sha_customize" angeben

5. Phase 5: Neue Stanzwerkzeugart testen

Phase 1: Arbeitsebene und Profil sowie Ausrichtungspunkte erstellen

Vorgehensweise:

1. Erstellen Sie in Ihrer Arbeitskopie der Datei sha_punch_functions.lsp (z. B. my_punch_func.lsp) einen neuen Eintrag für die Werkzeugart. Im folgenden Beispiel werden eine Arbeitsebene und das Profil sowie die Ausrichtungspunkte für ein dreieckiges Stanzwerkzeug erstellt.

;=====================================================
;
; TRIANGLES
;
;
;=====================================================
(defun sha-tri-profile
(
size
)
(let ((result nil)
(tool-wp (sha-tool-wp))
)
(create_workplane :new
:name tool-wp
)
;********* create Profile *******
(POLYGON
(gpnt2d (- (/ size 2)) (- (/ size 3)))
(gpnt2d (/ size 2) (- (/ size 3)))
(gpnt2d 0 (* (/ size 3) 2))
(gpnt2d (- (/ size 2)) (- (/ size 3)))
)
;********* create Adjustpoints *******
(C_POINT
0,0
(gpnt2d (/ size 2) (* (/ size 3) 2))
(gpnt2d (- (/ size 2)) (* (/ size 3) 2))
(gpnt2d 0 (- (/ size 3)))
)
(setq result (sha-profile-of-wp tool-wp))
(delete_3d (sha-absolute-name tool-wp))
result
)
)

2. Speichern Sie die Datei.

Stellen Sie sicher, dass die Ausschnittdefinition mit dem zugehörigen Prägewerkzeug kompatibel ist.

Wenn Sie die neue Werkzeugdefinition in einer vollständig separaten Datei speichern, muss diese Datei mit den folgenden Paketanweisungen beginnen:

• (in-package :sheet-advisor)

• (use-package :oli)

Phase 2: Neue Stanzwerkzeugart in der Tabelle "Stanzwerkzeugarten" deklarieren

Vorgehensweise:

1. Öffnen Sie die Definitionsdatei für die Fertigungsstätte (Ihre Arbeitskopie der Datei sha_demoshop.lsp, z. B. my_shop.lsp).

2. Führen Sie einen Bildlauf zur Tabelle "Stanzwerkzeugarten" durch.

3. Fügen Sie den Namen der neuen tri Stanzwerkzeugart hinzu. Die resultierende Tabelle "Stanzwerkzeugarten" wird weiter unten gezeigt.

:TABLE-TITLE "Punch Types"
:COLUMNS
( :TOOL_TYPE :DESCRIPTION ) ; The :TOOL_TYPE column must exist
:COLUMN-NAMES
("Tool Type" "Description")
:UNITS
( nil nil )
:CONTENTS
(
; v localizable name
("tri" "Triangle")
("rnd" "Round")
("rect_sharp" "Rectangle Sharp")
("rect_rnded" "Rectangle Rounded")
...

Phase 3: Werkzeugtabelle für die neue Stanzwerkzeugart hinzufügen

Vorgehensweise:

1. Öffnen Sie die neue Fertigungsstätten-Definitionsdatei (z. B. my_shop.lsp), in der Sie die neue Werkzeugtabelle hinzufügen möchten.

2. Kopieren Sie eine vorhandene Werkzeugtabelle, oder erstellen Sie eine neue Werkzeugtabelle in der Definitionsdatei der Fertigungsstätte.

3. Geben Sie in dieser Tabelle die Parameterdatensätze (Bemaßungen, ID, fertigungsgerechte Markierung usw.) für die neue Werkzeugart an.

4. Geben Sie den Namen der neuen Stanzwerkzeugfunktion in der Zeile :PROF_FNC an.

5. Stellen Sie sicher, dass in der neuen Werkzeugtabelle keine :PROF_WP-Anweisung enthalten ist. :PROF_WP ist für nicht parametrische Werkzeuge gedacht.

Weiter unten wird ein Beispiel der Werkzeugtabelle für die neue Werkzeugart tri angezeigt.

(sha-define-shop-table "tri"
:TABLE-TITLE "Triangle"
:COLUMNS
(:SIZE :TOOL_ID
:DESCR :MIN_THICK
:MAX_THICK :PREFERENCE :ADVICE
)
:COLUMN-NAMES
( "Size" "Tool Id" "Descr" "Min Thick" "Max Thick" "Pref"
"Advice")
:UNITS
( :mm nil
nil :mm
:mm nil
nil)
:CONTENTS
(
(6.10 "01004"
"TRA" 0
1 :PREF
"-")
(7.00 "01012"
"RVX" 0
1.6 :NONPREF
"-")
(8.00 "01024"
"GL2" 0
2.0 :PREF
"-")
(10.00 "01136"
"OLN" 0
2.0 :PREF
"-")
)
:KEY (:SIZE )
:DISPLAY (:SIZE :PREFERENCE :ADVICE)
:FLAT-TEXT (:TOOL_ID)
; unique, not displayable column entries
:PROF_FNC sha-tri-profile
)

Phase 4: Neue Werkzeugfunktion in der Datei "sha_customize" angeben

Um sicherzustellen, dass die neue Werkzeugfunktion beim Starten von Creo Elements/Direct Sheet Metal automatisch geladen wird, müssen Sie die Werkzeugfunktion in der Datei sha_customize angeben.

Wenn der Name der benutzerdefinierten Werkzeugfunktionsdatei z. B. my_punch_func.lsp ist, müssen Sie die folgende Zeile an die Datei sha_customize anfügen:

sha-tdb-load "my_punch_func.lsp"

Stellen Sie sicher, dass die angepasste Fertigungsstättendatei in der Datei sha_customize angegeben ist. Weitere Informationen finden Sie unter Benutzerdefinierte TDB-Dateien implementieren.

Phase 5: Neue Stanzwerkzeugart testen

Führen Sie die folgenden Schritte durch, um die neue Stanzwerkzeugart zu testen:

1. Verwenden Sie eine der folgenden Methoden, um die neue Stanzwerkzeugart in Creo Elements/Direct Sheet Metal zu laden:

◦ Creo Elements/Direct Sheet Metal neu starten

Oder:

◦ Wenn Creo Elements/Direct Sheet Metal bereits ausgeführt wird, klicken Sie im unteren Bereich des Creo Elements/Direct Sheet Metal Fensters in die Befehlszeile, und geben Sie folgenden Befehl ein, um die Definitionsdatei der Fertigungsstätte zu laden:

(sha-tdb-load "my_shop.lsp")

2. Wählen Sie im Menü Stanzwerkzeug die Option Dreieck.

3. Klicken Sie auf Werkzeuge. Die neuen dreieckigen Stanzwerkzeuge sind jetzt in einer separaten Auswahlliste aufgeführt.

4. Wählen Sie das gewünschte dreieckige Stanzwerkzeug, und wenden Sie es an. Das Ergebnis dieses Vorgangs sollte dem folgenden Beispiel ähneln.

Abbildung 182. Abbildung 3. Dreieckige Stanzung

5. Untersuchen Sie die resultierende Stanzung.

Nicht parametrische Stanzwerkzeugarten

Zusätzlich zu den parametrischen Stanzwerkzeugarten werden eine Reihe von nicht parametrischen Stanzwerkzeugarten bereitgestellt, die Sie nach Bedarf verwenden können. Ein nicht parametrisches Werkzeug wird durch einen einzelnen Parameterdatensatz definiert. Dadurch wird impliziert, dass ein solches Werkzeug nur in einer einzigen Größe verfügbar ist.

Wenn Sie eines dieser vordefinierten nicht parametrischen Stanzwerkzeuge verwenden möchten, deklarieren Sie die entsprechende Werkzeugart in der Tabelle "Stanzwerkzeugarten" in der Fertigungsstätten-Definitionsdatei. Fügen Sie anschließend die zugehörige Werkzeugtabelle zur Definitionsdatei der Fertigungsstätte hinzu. Die Methode wird weiter unten im Abschnitt Eintrag für nicht parametrische Stanzwerkzeugart hinzufügen anhand eines Beispiels veranschaulicht.

Alternativ können Sie Ihre eigenen nicht parametrischen Stanzwerkzeuge von Grund auf neu erstellen. Das Verfahren wird im folgenden Abschnitt beschrieben.

Eintrag für nicht parametrische Stanzwerkzeugart hinzufügen

Führen Sie die folgenden Schritte durch, wenn Sie eine nicht parametrische Stanzwerkzeugart in der TDB hinzufügen möchten:

1. Verwenden Sie die Creo Elements/Direct Modeling Befehle unter 2D erstellen oder zugeordnete Makrobefehle, um das Profil des neuen Stanzwerkzeugs zu erstellen. Fügen Sie diesem Profil Punkte hinzu, um sie als Ausrichtungspunkte zu verwenden.

2. Speichern Sie die Arbeitsebene und das Profil im Format 3D-Daten.

3. Fügen Sie das neue Stanzwerkzeug zur Fertigungsstätten-Definitionsdatei hinzu.

Wenn Sie z. B. ein neuartiges nicht parametrisches Stanzwerkzeug mit dem Namen "snap-in slot" hinzufügen möchten, gehen Sie folgendermaßen vor:

1. Erstellen Sie ein Werkzeugprofil wie im Beispiel, das in der folgenden Abbildung gezeigt wird. Das Profil muss um den Ursprung (0,0) der Arbeitsebene zentriert sein.

Abbildung 183. Abbildung 4. Beispielprofil für ein nicht parametrisches Stanzwerkzeug

2. Fügen Sie Punkte hinzu, die als Ausrichtungspunkte dienen können. Vorhandene Stanzwerkzeuge können bei der Positionierung von Ausrichtungspunkten hilfreich sein.

3. Speichern Sie das neue Werkzeug im Standardverzeichnis für Creo Elements/Direct Sheet Metal Stanzwerkzeuge oder im benutzerdefinierten Stanzwerkzeug-Verzeichnis. Das Standardverzeichnis ist:

$INSTALLDIR/personality/SheetAdvisor/punch

Creo Elements/Direct Modeling lädt die Arbeitsebene und die Teile-Informationen aus den Verzeichnissen, die als Suchverzeichnisse angegeben sind. Um den Suchverzeichnissen ein Verzeichnis hinzuzufügen, verwenden Sie folgende Syntax:

(SEARCH_DIRECTORIES :append "$INSTALLDIR/personality/SheetAdvisor/punch")

Geben Sie einen Dateinamen an, der die Funktion des Werkzeugs identifiziert (z. B. snap_slot.sdw). Wenn die Schaltfläche Erstrangige Exemplardateien im Menü Datei deaktiviert ist, erstellt Creo Elements/Direct Modeling automatisch die zugehörige Datei .sdwc zusammen mit der Datei .sdw. Wenn die Schaltfläche aktiviert ist, wird nur eine Datei (.sdwc) erstellt. Sie können eine beliebige der beiden Methoden verwenden.

Alternativ können Sie den vollständigen Pfadnamen für die Datei angeben, in der Sie die Arbeitsebene sowie das Profil des neuen Stanzwerkzeugs speichern möchten. Beispiel: Wenn Ihr Name Jane lautet und Sie die neue Werkzeugdatei im Standardverzeichnis speichern möchten, geben Sie einen Pfad- und Dateinamen ähnlich dem Folgenden an:

/users/jane/snap_slot.sdw

4. Fügen Sie im Abschnitt "Stanzwerkzeugarten" der Fertigungsstätten-Definitionsdatei eine Definitionszeichenfolge, z. B. "Triangle", für die neue Stanzwerkzeugart hinzu, die in der TDB hinzugefügt werden soll.

5. Geben Sie im unteren Bereich des Abschnitts "punch tools" der Fertigungsstätten-Definitionsdatei eine Definitionstabelle für das neue Stanzwerkzeug an. Sie können die Tabelle von Grund auf neu erstellen oder eine vorhandene Stanzwerkzeugtabelle kopieren und bearbeiten. Eine Beispieltabelle wird weiter unten gezeigt. Diese Tabelle umfasst den Standardverzeichnispfad, der im vorherigen Schritt erwähnt wurde.

(sha-define-shop-table "snap_slot"
:TABLE-TITLE "Snap-in Slot"
:COLUMNS
(:IN_DIA :OUT_DIA :WIDTH :DEPTH :ANGLE :TOOL_ID :DESCR
:MIN_THICK :MAX_THICK :PREFERENCE :ADVICE :PROF_WP)
:COLUMN-NAMES
("Up Rad" "Lo Rad" "Width" "Depth" "Angle" "Tool Id" "Descr"
"Min Thick" "Max Thick" "Pref" "Advice" "Prof WP")
:UNITS
(:mm :mm :mm :deg nil nil nil
:mm :mm nil nil nil)
:CONTENTS (
(10.0 6.0 6.0 10 -12 "SHS7" ""
1 1.7 :PREF "-" "/users/jane/snap_slot.sdw")
)
:KEY (:IN_DIA :OUT_DIA :SLOT_WIDTH :ANGLE :NR_SLOTS)
:DISPLAY (:IN_DIA :OUT_DIA :SLOT_WIDTH :ANGLE :NR_SLOTS :PREFERENCE :ADVICE)
:FLAT-TEXT (:TOOL_ID)
:HELP "/users/name/snap"
)

In dieser Tabelle wird ein einzelner Wert pro Tabellenspalte angegeben, weil das (nicht parametrische) Werkzeug nur in einer Größe verfügbar ist.

Stellen Sie sicher, dass die angepasste Fertigungsstättendatei in der Datei sha_customize angegeben ist. Weitere Informationen finden Sie unter Benutzerdefinierte TDB-Dateien implementieren.

Die Anweisung /users/jane/snap_slot.sdw in der Spalte Prof WP ist nur ein Beispiel eines Pfadnamens für die Datei, in der Sie die neue Arbeitsebene für das Werkzeug und das Profil gespeichert haben.

6. Stellen Sie sicher, dass das Verzeichnis, in dem Sie die neue Werkzeugdatei speichern möchten, in der Datei sha_customize angegeben ist. Wenn Sie das neue Werkzeug im Standardverzeichnis für Stanzwerkzeuge speichern, müssen Sie nicht den vollständigen Pfadnamen angeben.

7. Sie können das neue nicht parametrische Stanzwerkzeug testen (optional). Die allgemeine Vorgehensweise entspricht den Schritten unter Phase 5: Neue Stanzwerkzeugart testen.